~dricottone/mail-filters

ref: 4286bae71b4ca1c9203a3a3ebf1ff4701855e4b7 mail-filters/src/fanfiction.awk -rwxr-xr-x 1004 bytes
4286bae7 — Dominic Ricottone Revamping Mailman filter with external digestion 4 years ago 
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

#!/bin/awk -f

# fanfiction.awk
# ==============
# A filter (as for mutt or aerc) intended to clean & decorate plaintext mail
# from FanFiction.net, highlighting descriptive information

BEGIN {
  highlight="\033[44m";
  dim="\033[2m";
  cyan="\033[36m";
  reset="\033[0m";

  comma_replacement=reset ", " highlight;
  brace_replacement=reset "] " highlight;
  close_brace_replacement=reset "] ";
}
{
  # stop processing at end of mail, marked by website URL
  if ($0 ~ /^FanFiction http/) exit 0;

  if ($0 ~ /^New (story|chapter) from/) {
    $4=cyan $4;
    $0=$0 reset;
  }
  else if ($0 ~ /^(Words|Genre|Rated):/) {
    $1=$1 dim cyan;
    $0=$0 reset;
  }
  else if ($0 ~ /^Character:/) {
    if ($2 ~ /^\[/) {
      $2="[" highlight substr($2,2);
    }
    else {
      $2=highlight $2;
    }
    gsub(/, /,comma_replacement);
    gsub(/\] /,brace_replacement);
    if ($NF ~ /]\s+$/) {
      sub(/]\s+$/,close_brace_replacement,$NF);
    }
    else {
      $0=$0 reset;
    }
  }

  print $0;
}